home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Fritz: All Fritz
/
All Fritz.zip
/
All Fritz
/
FILES
/
EDUCTRIC
/
PSPICE1.LZH
/
PSPICE1.ZIP
/
EXAMPLE1.CIR
< prev
next >
Wrap
Text File
|
1984-01-05
|
1KB
|
42 lines
EXAMPLE1 - AN ILLUSTRATION OF ALL COMMANDS
*
* THIS CIRCUIT USES ALL POSSIBLE COMMANDS TO CREATE THE MAXIMUM AMOUNT OF
* OUTPUT POSSIBLE FROM SUCH A SMALL CIRCUIT. NORMALLY, ONLY A FEW KINDS OF
* OUTPUT (SUCH AS TRANSIENT ANALYSIS) WOULD BE RUN.
*
.OPT ACCT LIST NODE OPTS NOPAGE RELTOL=.001
.WIDTH OUT=80
.TEMP 35
.TF V(5) VIN
.DC VIN -0.25 0.25 0.005
.AC DEC 10 1 10GHZ
.TRAN/OP 5NS 500NS
.SENS V(5)
.NOISE V(5) VIN 20
.FOUR 5MEG V(5)
VIN 100 0 AC 1 SIN(0 0.1 5MEG)
VCC 101 0 DC 12
VEE 102 0 -12
Q1 4 2 6 QNL
Q2 5 3 6 QNL
RS1 100 2 1K
RS2 3 0 1K
RC1 4 101 CRES 10K
RC2 5 101 CRES 10K
Q3 6 7 102 QNL
Q4 7 7 102 QNL
RBIAS 7 101 20K
CLOAD 4 5 5PF
.MODEL CRES RES (R=1 TC1=.02 TC2=.0045)
.MODEL QNL NPN (BF=80 RB=100 CCS=2PF TF=0.3NS TR=6NS CJE=3PF CJC=2PF
+ VA=50)
.PRINT DC V(4) V(5)
.PLOT DC IC(Q2)
.PRINT AC VM(5) VP(5)
.PLOT AC VCM(Q2) VCP(Q2)
.PRINT NOISE INOISE ONOISE
.PLOT NOISE INOISE ONOISE
.PRINT TRAN V(4) V(5)
.PLOT TRAN V(4) V(5) I(CLOAD)
.PROBE
.END